root/1.8.3/branches/autoconf/configure.in

### autoconf file for PennMUSH
### This file uses tests from the Autoconf Macro Archive.
### It is available at http://autoconf-archive.cryp.to/ 
### The actual tests used are in ./aclocal.m4. DO NOT AUTO-GENERATE
### that file with aclocal.

AC_INIT(configure.in)
AC_CONFIG_HEADERS(config.h)

AC_LANG(C)

### Programs

AC_CHECK_PROG(CAT, cat, "$as_dir/$ac_word$ac_exec_ext")
AC_PROG_CC
AC_CHECK_PROG(CHMOD, chmod,  "$as_dir/$ac_word$ac_exec_ext")
AC_CHECK_PROG(CP, cp, "$as_dir/$ac_word$ac_exec_ext")
AC_CHECK_PROG(ECHO, echo, "$as_dir/$ac_word$ac_exec_ext")
AC_PROG_INSTALL
AC_PROG_LN_S
AC_ARG_VAR(MAKE, Path to GNU make)
AC_CHECK_PROG(MAKE, make, "$as_dir/$ac_word$ac_exec_ext")
AC_ARG_VAR(PERL, Path to perl)
AC_CHECK_PROG(PERL, perl, "$as_dir/$ac_word$ac_exec_ext")
AC_CHECK_PROG(TEST, test, "$as_dir/$ac_word$ac_exec_ext")
AC_CHECK_PROG(TOUCH, touch, "$as_dir/$ac_word$ac_exec_ext")
AC_CHECK_PROG(RM, rm, "$as_dir/$ac_word$ac_exec_ext")

AC_CHECK_PROG(UPTIME, uptime, "$as_dir/$ac_word$ac_exec_ext")
if test "x$ac_cv_prog_UPTIME" != x; then
 AC_DEFINE_UNQUOTED([UPTIME_PATH], "$ac_cv_prog_UPTIME")
fi

AC_CHECK_PROG(SENDMAIL, sendmail, "$as_dir/$ac_word$ac_exec_ext")
if test "x$ac_cv_prog_SENDMAIL" != x; then
 AC_DEFINE([HAVE_SENDMAIL])
 AC_DEFINE_UNQUOTED([SENDMAIL], "$ac_cv_prog_SENDMAIL")
fi


### Headers
# Usually there's no need to check for standard C89 headers.

# <stdint.h> is checked by this.
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_HEADER_TIME
AC_CHECK_HEADER(sys/time.h, [AC_DEFINE(I_SYS_TIME)])
AC_CHECK_HEADER(arpa/inet.h, [AC_DEFINE(I_ARPA_INET)])
AC_CHECK_HEADER(arpa/nameser.h, [AC_DEFINE(I_ARPA_NAMESER)])
AC_CHECK_HEADER(fcntl.h, [AC_DEFINE(I_FCNTL)])
AC_CHECK_HEADER(floatingpoint.h, [AC_DEFINE(I_FLOATINGPOINT)])
AC_CHECK_HEADER(libintl.h, [AC_DEFINE(I_LIBINTL)])
AC_CHECK_HEADER(malloc.h, [AC_DEFINE(I_MALLOC)])
AC_CHECK_HEADER(netdb.h, [AC_DEFINE(I_NETDB)])
AC_CHECK_HEADER(netinet/in.h, [AC_DEFINE(I_NETINET_IN)])
AC_CHECK_HEADER(netinet/tcp.h, [AC_DEFINE(I_NETINET_TCP)])
AC_CHECK_HEADER(sys/errno.h, [AC_DEFINE(I_SYS_ERRNO)])
AC_CHECK_HEADER(sys/file.h, [AC_DEFINE(I_SYS_FILE)])
AC_CHECK_HEADER(sys/in.h, [AC_DEFINE(I_SYS_IN)])
AC_CHECK_HEADER(sys/mman.h, [AC_DEFINE(I_SYS_MMAN)])
AC_CHECK_HEADER(sys/page.h, [AC_DEFINE(I_SYS_PAGE)])
AC_CHECK_HEADER(sys/param.h, [AC_DEFINE(I_SYS_PARAM)])
AC_CHECK_HEADER(sys/socket.h, [AC_DEFINE(I_SYS_SOCKET)])
AC_CHECK_HEADER(sys/stat.h, [AC_DEFINE(I_SYS_STAT)])
AC_CHECK_HEADER(sys/types.h, [AC_DEFINE(I_SYS_TYPES)])

### C language support
# Only need to check C99 and GNU extensions

AC_C_RESTRICT
AC_C_INLINE
AX_C___ATTRIBUTE__

if test "$ac_cv___attribute__" = "yes"; then
 AX_GCC_MALLOC_CALL
fi

### Types
# Again, no need to check for standard C89 types.

AC_TYPE_PID_T
TYPE_SOCKLEN_T
AC_TYPE_UINT16_T
AC_TYPE_UINT32_T

### Libraries
AC_CHECK_LIB(m, sin)
AC_CHECK_LIB(intl, gettext)
AC_CHECK_LIB(crypt, crypt)
LIB_SOCKET_NSL

with_ssl=set
CHECK_SSL
if test "$HAVE_SSL" = "yes"; then
    AC_DEFINE(HAVE_SSL)
fi

### Databases

AX_LIB_MYSQL()
AX_LIB_POSTGRESQL()
AX_LIB_SQLITE3()



### Functions
AC_CHECK_FUNC(bindtextdomain, [AC_DEFINE(HAS_BINDTEXTDOMAIN)])
AC_CHECK_FUNCS(cbrt)
AC_CHECK_FUNC(crypt, [AC_DEFINE(HAS_CRYPT)])
AC_CHECK_FUNC(fpsetmask, [AC_DEFINE(HAS_FPSETMASK)])
AC_CHECK_FUNC(fpsetround, [AC_DEFINE(HAS_FPSETROUND)])
AC_CHECK_FUNC(gai_strerror, [AC_DEFINE(HAS_GAI_STRERROR)])
AC_CHECK_FUNC(getaddrinfo, [AC_DEFINE(HAS_GETADDRINFO)])
AC_CHECK_FUNC(getdate, [AC_DEFINE(HAS_GETDATE)])
AC_CHECK_FUNC(gethostbyname2, [AC_DEFINE(HAS_GETHOSTBYNAME2)])
AC_CHECK_FUNC(getnameinfo, [AC_DEFINE(HAS_GETNAMEINFO)])
AC_CHECK_FUNC(getpagesize, [AC_DEFINE(HAS_GETPAGESIZE)])
AC_CHECK_FUNC(getrlimit, [AC_DEFINE(HAS_GETRLIMIT)])
AC_CHECK_FUNC(getrusage, [AC_DEFINE(HAS_GETRUSAGE)])
AC_CHECK_FUNC(gettext, [AC_DEFINE(HAS_GETTEXT)])
AC_CHECK_FUNC(inet_pton, [AC_DEFINE(HAS_INET_PTON)])
AC_CHECK_FUNC(setitimer, [AC_DEFINE(HAS_ITIMER)])
AC_CHECK_FUNC(setlocale, [AC_DEFINE(HAS_SETLOCALE)])
AC_CHECK_FUNC(setpgrp, [AC_DEFINE(HAS_SETPGRP)])
AC_FUNC_SETPGRP
AC_CHECK_FUNCS(getuid geteuid seteuid)
AC_CHECK_FUNCS(getpriority setpriority)
AC_CHECK_FUNC(sigaction, [AC_DEFINE(HAS_SIGACTION)])
AC_CHECK_FUNC(sigprocmask, [AC_DEFINE(HAS_SIGPROCMASK)])

AC_FUNC_SNPRINTF
if test "x$ac_cv_have_working_snprintf" = xyes; then
AC_DEFINE(HAS_SNPRINTF)
fi
if test "x$ac_cv_have_working_vsnprintf" = xyes; then
AC_DEFINE(HAS_VSNPRINTF)
fi

AC_CHECK_FUNC(socketpair, [AC_DEFINE(HAS_SOCKETPAIR)])

# Assume that the strn versions are also there if these are
AC_CHECK_FUNCS(strcasecmp _stricmp)

AC_CHECK_FUNC(strdup, [AC_DEFINE(HAS_STRDUP)])
AC_FUNC_STRCOLL
AC_CHECK_FUNC(strxfrm, [AC_DEFINE(HAS_STRXFRM)])
AC_CHECK_FUNC(sysconf, [AC_DEFINE(HAS_SYSCONF)])
AC_CHECK_FUNC(textdomain, [AC_DEFINE(HAS_TEXTDOMAIN)])

AC_CHECK_FUNC(waitpid, [AC_DEFINE(HAS_WAITPID)],
[AC_MSG_CHECKING(checking for union wait)
AC_CHECK_TYPES([union wait], [AC_DEFINE(UNION_WAIT)
AC_MSG_RESULT(yes)], AC_MSG_RESULT(no),
[AC_INCLUDES_DEFAULT
#ifdef I_SYS_WAIT
#include <sys/wait.h>
#endif
])])


### Variables, constants and defines

AC_CHECK_DECLS(h_errno, [AC_DEFINE(HAVE_H_ERRNO)],,[AC_INCLUDES_DEFAULT
#ifdef I_NETDB
#include <netdb.h>
#endif
])

# Which flavor of child killing to use? Prefer SIGCHLD.

AC_CHECK_DECLS(SIGCHLD, [AC_DEFINE(HAVE_SIGCHLD)],,[AC_INCLUDES_DEFAULT
#include <signal.h>
])

AC_CHECK_DECLS(SIGCLD, [AC_DEFINE(HAVE_SIGCLD)],,[AC_INCLUDES_DEFAULT
#include <signal.h>
])


### Files
AC_CHECK_FILE(/dev/urandom, [AC_DEFINE(HAS_DEV_URANDOM)])

### Misc features
AC_ARG_ENABLE(ipv6,  AS_HELP_STRING([--disable-ipv6], [Don't use IPv6 networking]), enable_ipv6=$enableval, enable_ipv6=yes)

if test "$enable_ipv6" = "no"; then
AC_DEFINE(FORCE_IPV4)
fi

AC_ARG_ENABLE(nls, AS_HELP_STRING([--disable-nls], [Don't use message-translation]), enable_nls=$enableval, enable_nls=yes)

if test "$enable_nls" = "no"; then
AC_DEFINE(DONT_TRANSLATE)
fi

### Output

AC_CONFIG_FILES([Makefile src/Makefile])
AC_CONFIG_FILES([utils/mkcmds.sh game/txt/compose.sh], [chmod +x utils/mkcmds.sh game/txt/compose.sh])
AC_OUTPUT